Adding nice selenium-results to build report - Selenium

This page describes how to make CruiseControl to show nice build results report from the selenium-results.html. This solution works only with Mozilla Firefox (actually it does not work with IE, and I did not tested with other browsers), and is based on assumption that selenium-fitrunner or something similar is used to produce selenium-results.html on file system.

First it is necessary to make CruiseControl merge selenium-results.html into xml log. It easily could be done in CruiseControl config.xml as follows if the html is valid XHTML!

    <log>
      <merge file="${workdir}/target/logs/selenium-results.html"/>
    </log>

The only problem is that valid XHTML selenium-results.html is required. For this it is necessary to patch viewResults.jsp from the selenium-fitrunner to produce html with XHTML header as follows, and make sure all html is valid, i.e. all tags are closed.

              <!DOCTYPE html
                PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
                "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd"> 
              <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
              ......

Notice, that selenium javascripts use innerHTML() to retrive selenium result table and post results. Unfortunetly, IE 6.0 does not produce XHTML with this method, while Firefox does, luckily.

Important, even though, avoid using single tags (that don't require closing tag), since Firefox (at least 1.5) still does not genereate closed tag for them. E.g. even if you write <br/> in your test*.html, Firefox will write <br> without closing </br> (since it is impossible), and selenium-results.html will be invalid XHML.

These two issues might be fixed in nearest future.

Well, finally when you ensured that postResults returns valid XHTML (i.e., when you still can see results table in your browser at the end of the tests after you patched postResults), it is time to learn CruiseControl to include selenium-results.html into build results report.

To make CruiseControl show selenium-results report, I've created selenium.xsl, that must be put into <cruiseconrol webapp>/xsl/ dir, and included (imported) into buildresults.xsl as follows below.

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  .....
  <xsl:import href="selenium.xsl"/>
  .....
  <xsl:template match="/">
   .....
    <p><xsl:apply-templates select="$cruisecontrol.list" mode="selenium"/></p>
   .....
  </xsl:template>
  .....
</xsl:stylesheet>

And here is selenium.xsl itself, that is based on unittests.xsl indeed:

<?xml version="1.0"?>

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
 xmlns:html="http://www.w3.org/1999/xhtml">
  <xsl:output method="html"/>
    
  <xsl:variable name="testsuite" select="/cruisecontrol/html:html/html:body/html:table"/>
  <xsl:variable name="testsuite.result" select="$testsuite/html:tr[html:td[1]/text()='result:']/html:td[2]"/>
  <xsl:variable name="testsuite.numTestPasses" select="$testsuite/html:tr[html:td[1]/text()='numTestPasses:']/html:td[2]"/>
  <xsl:variable name="testsuite.numTestFailures" select="$testsuite/html:tr[html:td[1]/text()='numTestFailures:']/html:td[2]"/>
  <xsl:variable name="testsuite.numCommandPasses" select="$testsuite/html:tr[html:td[1]/text()='numCommandPasses:']/html:td[2]"/>
  <xsl:variable name="testsuite.numCommandErrors" select="$testsuite/html:tr[html:td[1]/text()='numCommandErrors:']/html:td[2]"/>
  <xsl:variable name="testsuite.numCommandFailures" select="$testsuite/html:tr[html:td[1]/text()='numCommandFailures:']/html:td[2]"/>

  <xsl:template match="/" mode="selenium">
        <table align="center" cellpadding="2" cellspacing="0" border="0" width="98%">
            <tr>
                <td class="unittests-sectionheader" colspan="4">
                   &#160;Selenium Tests 
                <xsl:if test="$testsuite.result != ''">
                   passed: <xsl:value-of select="$testsuite.numTestPasses"/>,
                     failed: <xsl:value-of select="$testsuite.numTestFailures"/>;
                   Commands passed: <xsl:value-of select="$testsuite.numCommandPasses"/>,
                     failed: <xsl:value-of select="$testsuite.numCommandFailures"/>,  
                     broken: <xsl:value-of select="$testsuite.numCommandErrors"/>
                </xsl:if>
                </td>
            </tr>
            <xsl:choose>
                <xsl:when test="$testsuite.result = 'passed'">
                    <tr>
                        <td colspan="4" class="unittests-data">
                            All Tests Passed
                        </td>
                    </tr>
                </xsl:when>
                <xsl:when test="$testsuite.result = 'failed'">
                    <tr>
                        <td colspan="4" class="unittests-data">
                            <xsl:apply-templates select="$testsuite/html:tr/html:td/html:div/html:table[html:tbody/html:tr/@bgcolor='#ffcfcf']" mode="selenium"/>
                        </td>
                    </tr>
                </xsl:when>
                <xsl:otherwise>
                    <tr>
                        <td colspan="2" class="unittests-data">
                            No Tests Run
                        </td>
                        <td colspan="2" class="unittests-error">
                            This project doesn't have selenium tests
                        </td>
                    </tr>
                </xsl:otherwise>

            </xsl:choose>
        </table>
  </xsl:template>

  <xsl:template match="html:table" mode="selenium">
    <xsl:copy>
        <xsl:copy-of select="@*"/>
        <xsl:apply-templates select="html:tbody/html:tr[@bgcolor='#ffcfcf']" mode="selenium"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="*" mode="selenium">
    <xsl:copy-of select="."/>
  </xsl:template>

  <xsl:template match="/">
      <xsl:apply-templates select="." mode="selenium"/>
  </xsl:template>
</xsl:stylesheet>

Finally, if you're lucky, you'll see something like the following screen shot shows (tested with CruiseControl 2.3.1 (java)):